---

为什么渲染顺序很重要

我们在unity中的渲染顺序是视野方向从后往前渲染，如果采取从前往后渲染，前方遮挡物如果为不透明物体，则视野中会出现不透明物体在透明物体前面的假象，如果物体为半透明物体，则会出现渲染颜色的混合结果完全反过来，同样会出现后方物体在前方的假象。

unity渲染队列

在unity中，索引号越小的越先渲染，括号内为数值。
Background(1000)>Geometry(2000)>AlphaTest(2450)>Transparent(3000)>Overlay(4000)
透明度测试在AlphaTest队列内渲染即在所有不透明物体渲染之后进行统一渲染以更高效

透明度测试与透明度混合

透明度测试其实无法得到真正的半透明效果，但是可以让一部分物体被剔除

代码

解释：我们在代码中的Tags标签中我们需要把Queue标签设置为AlphaTest。
在unity中使用内置函数clip（）丢掉像素小于0的像素点，利用这个效果，美术调节滑杆cutoff或程序调节变量cutoff可以实现遮挡剔除。

Shader "Unity Shaders Book/Chapter 8/Alpha Test" {
	Properties {
		_Color ("Color Tint", Color) = (1, 1, 1, 1)
		_MainTex ("Main Tex", 2D) = "white" {}
		_Cutoff ("Alpha Cutoff", Range(0, 1)) = 0.5
	}
	SubShader {
		Tags {"Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="TransparentCutout"}
		
		Pass {
			Tags { "LightMode"="ForwardBase" }
			
			CGPROGRAM
			
			#pragma vertex vert
			#pragma fragment frag
			
			#include "Lighting.cginc"
			
			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			fixed _Cutoff;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 texcoord : TEXCOORD0;
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				float3 worldNormal : TEXCOORD0;
				float3 worldPos : TEXCOORD1;
				float2 uv : TEXCOORD2;
			};
			
			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				
				o.worldNormal = UnityObjectToWorldNormal(v.normal);
				
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				
				o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
				
				return o;
			}
			
			fixed4 frag(v2f i) : SV_Target {
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				
				fixed4 texColor = tex2D(_MainTex, i.uv);
				
				// 透明度测试，判断参数，如果texColor.a - _Cutoff<0则被剔除
				clip (texColor.a - _Cutoff);
				// Equal to 
//				if ((texColor.a - _Cutoff) < 0.0) {
//					discard;
//				}
				
				fixed3 albedo = texColor.rgb * _Color.rgb;
				
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
				
				fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));
				
				return fixed4(ambient + diffuse, 1.0);
			}
			
			ENDCG
		}
	} 
	FallBack "Transparent/Cutout/VertexLit"
}

下面是进行遮挡剔除的图片与其对应的设置的不同Alpha Cutoff值
另一个数值Render Queue=2450即标签AlphaTest确定的，可以后期条件，影响渲染的先后顺序

总结

我们在遮挡剔除后可以看到后面的背景，因为unity是从后往前渲染（括号指Render Queue值），Background（1000）最先被渲染，而方块被遮挡剔除，所以可以认为呈现了透明效果，视野穿透了方块，看到了Background和Geometry（2000）